;HMT NOESY optimized for Imino-Amino/Aromatics correlations with additional 15N filter for detection 
;avance-version (17/08/18)
;Hadamard NOESY
;homonuclear correlation via dipolar coupling 
;based on noesgpph
;dipolar coupling may be due to noe or chemical exchange.
;phase sensitive
;with gradient pulses in mixing time
;
;E. Kupce & R. Freeman, J. Magn. Reson. 162, 300-310 (2003)
;HMT preprint: 	arXiv:2004.13063
;
;$CLASS=HighRes
;$DIM=2D
;$TYPE=
;$SUBTYPE=
;$COMMENT=
;
;Experiment Setup:
;(1) use had_pl au-program to get the peak list
;(2) execute the 'wvm -a' command
;(3) start the experiment
;(4) use proc_had au-program for processing


#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>


define list<shape> SPL=<$VALIST>


"p2=p1*2"
"d26=1s/(cnst4*2)"

"DELTA=d19-p21/2"
"DELTA1=d26-p16-d16-p27*3-d19*5-p1*2/PI"
"DELTA2=d26-p16-d16-p27*2-p0-d19*5-de-8u"

"acqt0=-p1*2/PI"


1 ze
2 d11 do:f2 do:f3 BLKGRAD 
  d1 fq=cnst18(bf ppm):f3
10u pl12:f2 pl27:f3  
50u UNBLKGRAD
3 20u cpds7:f3 
  (p34:SPL ph0):f1
  20u do:f3
  p16:gp1
  d8
  lo to 3 times l1
  d16 pl1:f1
  ;(p34:SPL ph1):f1
  ;p16:gp1
 ; d16 pl1:f1
  (p29:sp11 ph5):f1
  2u pl1:f1
  (p1 ph6)
  DELTA1 fq=cnst20(bf ppm):f3 pl3:f3
  p16:gp2
  d16 pl18:f1
  (p27*0.231 ph3)
  d19*2
  (p27*0.692 ph3)
  d19*2
  (p27*1.462 ph3)
  DELTA
  (p21 ph0):f3
  DELTA
  (p27*1.462 ph4)
  d19*2
  (p27*0.692 ph4)
  d19*2
  (p0*0.231 ph4)
  4u
  p16:gp2
  d16 fq=cnst19(bf ppm):f3 pl12:f2 pl26:f3 
  4u BLKGRAD
  DELTA2
  go=2 ph31 cpds2:f2 cpds3:f3
  d11 do:f2 do:f3 mc #0 to 2 F1QF(SPL.inc)
exit

ph0=0 
ph1=2
ph3=0 0 1 1
ph4=2 2 3 3
ph5=0 2 1 3
ph6=2 0 3 1

ph31=2 0 3 1


;pl1 : f1 channel - power level for pulse (default) 
;pl3 : f3 channel - power level for soft 90 degree pulse p21
;pl12 : f2 channel - power level for decoupling during acquisition
;pl26 : f3 channel - power level for decoupling during acquisition
;pl27 : f3 channel - power level for decoupling during imino encoding
;p1 : f1 channel -  90 degree high power pulse
;p2 : f1 channel - 180 degree high power pulse
;p16: homospoil/gradient pulse                       [1 msec]
;p21 : f3 channel - soft 90 degree pulse only on amino protons (~180 us at 600 MHz)
;p34: f1 channel - 180 degree shaped pulse for Hadamard experiment created by wvm
;d1 : relaxation delay; 1-5 * T1
;d8 : NOESY delay per loop
;d16: delay for homospoil/gradient recovery
;cnst4: JNH coupling (e.g.110)
;cnst18: Imino offset (f3 ppm)
;cnst19: middle N15 offset (f3 ppm)
;cnst20: Amino offset (f3 ppm)
;cnst22: Bandwidth for Hadamard inversion encoding pulses 
;l1 : Number of HMT loops 
;cpd3: decoupling according to sequence defined by cpdprg3: garp4
;pcpd3: f3 channel - 90 degree pulse for decoupling sequence during acquisition 
;cpd7: decoupling according to sequence defined by cpdprg7: garp4
;pcpd7: f3 channel - 90 degree pulse for soft decoupling sequence during imino encoding
;ns: 1 * n
;ds: 4
;td1: size of Hadamard matrix, power of 2 (> # of peaks);
;FnMODE: QF


;for z-only gradients (optional):
;gpz1: 40%

;use gradient files (optional):   
;gpnam1: SMSQ10.100



;WaveMaker shapes
;use 'wvm -a' command to create the necessary shape files 
;sp11:wvm:H2Osinc: sinc90(1.5 ms)
;SPL:wvm:HTinv: sinc180(cnst22 Hz, PL, had)
;gp1:wvm:gwurst.100: wurst_g(5 G/cm, 1 ms)



;$Id: ht_noesygpph,v 1.2 2017/11/23 10:49:08 ber Exp $
